#!/bin/tcsh -f
#
# A little shell script to install font metrics (afm, tfm, vf, sty, fd)
# from CTAN:fonts/psfonts/...
#
# Usage: FontMetricInstall NAME-OF-SUPPLIER TYPEFACE-TO-INSTALL [...]
#
# Note: a) it is necessary to read the psnfss documentation!
#       b) *.map might have to be added to psfonts.map (for dvips)
#
# VK 22 Jun 94, 08 Jul 94, 30 Dec 94, 7 Jan 95; 29 Sep 95; 07,08 Apr 96
#

if ($#argv < 2) then
  echo '\
Usage: '"$0"' SUPPLIER TYPEFACE [TYPEFACE ...]\
  Copies TYPEFACE/{afm,tfm,vf}/* to $FONTS/{afm,tfm,vf}/SUPPLIER/TYPEFACE/\
         TYPEFACE/type1/* to $FONTS/type1/SUPPLIER/\
         TYPEFACE/tex/* to $TEXMF/tex/inputs/psnfss/SUPPLIER/\
         TYPEFACE/dvips/* to $TEXMF/dvips/SUPPLIER/\
  (SUPPLIER: e.g. adobe, bitstream; TYPEFACE: e.g. palatino, charter)\
  $FONTS defaults to $TEXMF/fonts/\
  $TEXMF must be set\
'
  exit 1
endif

if ( ! $?TEXMF ) then
  echo '$TEXMF is not set. Please set and re-run.'
  exit 5
endif

if ( ! $?FONTS ) then
  echo '$FONTS is not set - set to '"$TEXMF/fonts"
  setenv FONTS $TEXMF/fonts
endif

set supplier=$1

foreach typeface ( $argv[2-] )

echo ""
echo "Installing font $typeface in $FONTS/[afm|tfm|vf|type1]/$supplier"
echo "  (tex/* to ~/tex/inputs/psnfss/$supplier)"
echo "  (dvips/* to ~/dvips/$supplier)"

if ( ! -e $FONTS/afm/$supplier/$typeface ) mkdir -p $FONTS/afm/$supplier/$typeface
cp -p $typeface/afm/* $FONTS/afm/$supplier/$typeface
if ( ! -e $FONTS/tfm/$supplier/$typeface ) mkdir -p $FONTS/tfm/$supplier/$typeface
cp -p $typeface/tfm/* $FONTS/tfm/$supplier/$typeface
if ( ! -e $FONTS/vf/$supplier/$typeface ) mkdir -p $FONTS/vf/$supplier/$typeface
cp -p $typeface/vf/* $FONTS/vf/$supplier/$typeface

if ( ! -e $FONTS/type1/$supplier ) mkdir -p $FONTS/type1/$supplier
cp -p $typeface/type1/* $FONTS/type1/$supplier

if ( ! -e ~/tex/inputs/psnfss/$supplier ) mkdir -p ~/tex/inputs/psnfss/$supplier
cp -p $typeface/tex/*  ~/tex/inputs/psnfss/$supplier

if ( ! -e ~/dvips/$supplier ) mkdir -p ~/dvips/$supplier
cp -p $typeface/dvips/* ~/dvips/$supplier

end